#1645 - Introduce mumble module

modules/adblockplus/manifests/mumble.pp

 # == Class: adblockplus:mumble
 #
 # Create and maintain mumble (https://www.mumble.com) setups.
 #
 # === Parameters:
 #
 # [*package*]
 #   Overwrite the default package options, to fine-tune the target version (i.e.
 #   ensure => 'latest') or remove mumble (ensure => 'absent' or 'purged')
-#
-# === Hiera (only) Parameters:

[mathias, 2017/08/24 06:23:07]

Why Hiera only?

[f.lopez, 2017/08/25 19:04:40]

Well, I wanted to use it with hiera only, but yeah it might not make sense to do
that.

 #
 # [*certificate*]
 #   Certificate used to enable SSL connection with the server.
 #
 # [*private_key*]
 #   Private key used to enable SSL connection with the client.
 #
 # [*server_password*]
 #   String used to login into the server.
 #
 #
 # === Examples:
 #
 #   class {'adblockplus::mumble':
 #     package => {
 #       'ensure' => 'absent',
 #       },
 #     },
 #   }
 #
 class adblockplus::mumble (
   $package = {},
+  $certificate = {},
+  $private_key = {},
+  $server_password = 'changeme',
 ){
 
-  if ensure_state($ensure) {

[mathias, 2017/08/24 06:23:07]

The $ensure parameter is always undefined at this point - it is not declared
anywhere. If it where, however, you couldn't overwrite it anyway, variables in
Puppet are read-only after definition. You could use some $ensure_file or
$ensure_foobar to derive from it - and pass the original (!) to the package
resource (important! otherwise you corrupt requests for "latest" packages or a
particular version). But deriving $ensure parameters should be done based on
getparam(Package[...], 'ensure') anyway (to not miss some default defined
globally) and, in this case, you do not even use the $ensure stuff anywhere
except for the wrong use with the package resource below.

[f.lopez, 2017/08/25 19:04:40]

Acknowledged.

-    $ensure = 'present'
+  # https://forge.puppet.com/puppetlabs/stdlib#getparam
+  $package_ensure = $package['ensure']
+
+  # https://docs.puppet.com/puppet/latest/lang_conditional.html#selectors
+  $ensure = $package_ensure ? {
+    /^(absent|latest|present|purged|true)$/ => $package_ensure,
+    default => 'present',
   }
-  else {
-    $ensure = 'absent'
-  }
-
-  $certificate = hiera('adblockplus::mumble::certificate', undef)
-  $private_key = hiera('adblockplus::mumble::private_key', undef)
-  $server_password = hiera('adblockplus::mumble::server_password', undef)
 
   ensure_resource('package', $title, merge({
     name => 'mumble-server',
     ensure => $ensure,
   }, $package))
 
-  file{"/etc/mumble-server.ini":
+  file {'/etc/mumble-server.ini':
     owner => 'root',
     group => 'mumble-server',
     mode => 0640,
     content => template('adblockplus/mumble-server.ini.erb'),
     require => Package[$title],
     notify => Service['mumble-server'],
   }
 
-  service{'mumble-server':
+  service {'mumble-server':
     ensure => 'running',
     enable => true,
     require => Package[$title],
   }
 
-  if $mumble::certificate and $mumble::private_key {

[mathias, 2017/08/24 06:23:07]

Please do not replicate the legacy "give me the name of a file in the private
module" nonsense. Use a hash that may contain $source or $content (among other
stuff) in fully qualified fashion, and merge it with your own parameters before
passing it to ensure_resource() or similar.

[f.lopez, 2017/08/25 19:04:40]

Ok fair enough, working on this. Gonna send a new patch soon.

-    file {"/etc/mumble.crt":
-      ensure => 'file',
-      mode => 0644,
-      group => 'mumble-server',
-      before => File["/etc/mumble-server.ini"],
-      require => Package[$title],
-      source => "puppet:///modules/private/${mumble::certificate}",
-    }
+  # https://forge.puppet.com/puppetlabs/stdlib#getparam
+  $certificate_ensure = $certificate['ensure']
 
-    file {"/etc/mumble.key":
-      ensure => 'file',
-      mode => 0644,
-      group => 'mumble-server',
-      before => File["/etc/mumble-server.ini"],
-      require => Package[$title],
-      source => "puppet:///modules/private/${mumble::private_key}",
-    }
+  # https://docs.puppet.com/puppet/latest/lang_conditional.html#selectors
+  $ensure_certificate = $certificate_ensure ? {
+    /^(absent|latest|present|purged|true)$/ => $certificate_ensure,
+    default => 'absent',
   }
+
+  $default_cert_source = $certificate['content'] ? {
+    undef => 'puppet:///modules/private/mumble.crt',
+    default => undef,
+  }
+
+  ensure_resource('file', '/etc/mumble.crt', merge({
+    ensure => ensure_file_state($ensure_certificate),
+    mode => 0644,
+    path => '/etc/mumble.crt',
+    group => 'mumble-server',
+    before => File['/etc/mumble-server.ini'],
+    require => Package[$title],
+    source => $default_cert_source,
+  }, $certificate))
+
+  # https://forge.puppet.com/puppetlabs/stdlib#getparam
+  $private_key_ensure = $private_key['ensure']
+
+  # https://docs.puppet.com/puppet/latest/lang_conditional.html#selectors
+  $ensure_private_key = $certificate_ensure ? {
+    /^(absent|latest|present|purged|true)$/ => $private_key_ensure,
+    default => 'absent',
+  }
+
+  $default_pk_source = $private_key['content'] ? {
+    undef => 'puppet:///modules/private/mumble.key',
+    default => undef,
+  }
+
+  ensure_resource('file', 'mumble.key', merge({
+    ensure => ensure_file_state($ensure_private_key),
+    mode => 0644,
+    path => '/etc/mumble.key',
+    group => 'mumble-server',
+    before => File['/etc/mumble-server.ini'],
+    require => Package[$title],
+    source => $default_pk_source,
+  }, $private_key))
 }