Noissue - Use meson to build the C++ code

meson.build

-project('adblockpluscore', license: ['GPL3'])

[Wladimir Palant, 2017/10/11 10:00:47]

Meson 0.39.1 (what you currently get on Ubuntu) complains: "Not enough arguments
to project(). Needs at least the project name and one language"

I guess that you have a newer version installed, but adding 'cpp' parameter
won't hurt.

[hub, 2017/10/11 18:23:16]

Done.

+project('adblockpluscore', license: ['GPL3'], meson_version: '>0.40.0')
 
-emcc = find_program('emcc')
-nodejs = find_program('node')

[Wladimir Palant, 2017/10/11 10:00:47]

I tried reading Emscripten configuration and the following worked (note that
meson depends on Python3 so it doesn't introduce an additional dependency):

python = import('python3').find_python()

emscripten_config = get_option('emscripten-config')
command = run_command(python, '-c', 'import os.path,
sys;print(os.path.expanduser(sys.argv[1]))', emscripten_config)
if command.returncode() != 0
  error(command.stderr().strip())
endif
emscripten_config = command.stdout().strip()
message('Emscripten config file: ' + emscripten_config)

command = run_command(python, '-c', 'import
sys;exec(open(sys.argv[1]).read());print(EMSCRIPTEN_ROOT)', emscripten_config)
if command.returncode() != 0
  error(command.stderr().strip())
endif
emcc = join_paths(command.stdout().strip(), 'emcc')
emcc = find_program(emcc)

command = run_command(python, '-c', 'import
sys;exec(open(sys.argv[1]).read());print(NODE_JS)', emscripten_config)
if command.returncode() != 0
  error(command.stderr().strip())
endif
nodejs = find_program(command.stdout().strip(), 'node', 'nodejs')

[hub, 2017/10/11 18:23:17]

Done.

+# locate emscripten-config
+python = import('python3').find_python()
+emscripten_config = get_option('emscripten-config')
+command = run_command(python, '-c', 'import os.path, sys;print(os.path.expanduser(sys.argv[1]))', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+emscripten_config = command.stdout().strip()
+message('Emscripten config file: ' + emscripten_config)
 
-JS_LIBRARY = files('compiled/library.js')
+# locate emcc
+command = run_command(python, '-c', 'import sys;exec(open(sys.argv[1]).read());print(EMSCRIPTEN_ROOT)', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+emcc = join_paths(command.stdout().strip(), 'emcc')
+emcc = find_program(emcc)
+
+# locate node
+command = run_command(python, '-c', 'import sys;exec(open(sys.argv[1]).read());print(NODE_JS)', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+nodejs = find_program(command.stdout().strip(), 'node', 'nodejs')
+
+JS_LIBRARY = files(join_paths('compiled', 'library.js'))
+BINDINGS_JS_LIBRARY = files(join_paths('compiled', 'bindings', 'library.js'))
 BINDINGS_GENERATOR = 'bindings.cpp.js'
 BINDINGS_OUTPUT = 'bindings.js'
 COMPILER_OUTPUT = 'compiled.js'
 # params for emcc compilation
-ADDITIONAL_PARAMS = ['-O3', '-m32', '-std=c++1z', '--memory-init-file', '0',
-                     '--emit-symbol-map', '-Wall', '-Werror', '-fno-exceptions',
-                     '-fno-rtti', '--js-library', JS_LIBRARY]
+ADDITIONAL_PARAMS = [ '-O3', '-m32', '-std=c++1z', '--memory-init-file', '0',
+                      '--emit-symbol-map', '-Wall', '-Werror',
+                      '-fno-rtti' ]
+# additional params just for core
+CORE_PARAMS = [ '-fno-exceptions' ]
+
 DEFINES = []
 GENERATION_PARAMS = [
-    ['SHELL_FILE', '"' + meson.source_root() + '/compiled/shell.js"'],
-    ['ASM_JS', '2'],  # "almost asm"
-    ['TOTAL_MEMORY', 16*1024*1024],
-    ['TOTAL_STACK', 1*1024*1024],
-    ['ALLOW_MEMORY_GROWTH', 1],
-    ['NO_EXIT_RUNTIME', 1],
-    ['NO_DYNAMIC_EXECUTION', 1],
-    ['NO_FILESYSTEM', 1],
-    ['INVOKE_RUN', 0],
-    ['TEXTDECODER', 0],
-    ['EXPORTED_RUNTIME_METHODS', '["cwrap", "ccall", "stringToAscii"]']
+  ['SHELL_FILE', '"' +
+   join_paths(meson.source_root(), 'compiled', 'shell.js') +
+   '"'],
+  ['ASM_JS', '2'],  # "almost asm"
+  ['TOTAL_MEMORY', 16*1024*1024],
+  ['TOTAL_STACK', 1*1024*1024],
+  ['ALLOW_MEMORY_GROWTH', 1],
+  ['NO_EXIT_RUNTIME', 1],
+  ['NO_DYNAMIC_EXECUTION', 1],
+  ['NO_FILESYSTEM', 1],
+  ['INVOKE_RUN', 0],
+  ['TEXTDECODER', 0],
+  ['EXPORTED_RUNTIME_METHODS', '["cwrap", "ccall", "stringToAscii"]']
 ]
 
-bindings_sources = files(
-    'compiled/bindings/generator.cpp',
-    'compiled/bindings/main.cpp',
-)
-sources = files(
-    'compiled/bindings/runtime_utils.cpp',
-    'compiled/filter/ActiveFilter.cpp',
-    'compiled/filter/BlockingFilter.cpp',
-    'compiled/filter/CommentFilter.cpp',
-    'compiled/filter/ElemHideBase.cpp',
-    'compiled/filter/ElemHideEmulationFilter.cpp',
-    'compiled/filter/ElemHideException.cpp',
-    'compiled/filter/ElemHideFilter.cpp',
-    'compiled/filter/Filter.cpp',
-    'compiled/filter/InvalidFilter.cpp',
-    'compiled/filter/RegExpFilter.cpp',
-    'compiled/filter/WhitelistFilter.cpp',
-    'compiled/storage/FilterStorage.cpp',
-    'compiled/subscription/DownloadableSubscription.cpp',
-    'compiled/subscription/Subscription.cpp',
-    'compiled/subscription/UserDefinedSubscription.cpp',
-    'compiled/traceInit.cpp'
-)
 
-bindings_generator = custom_target('bindings-generator',
-                   input: bindings_sources + sources,
-                   output: BINDINGS_GENERATOR,
-                   command: [emcc, '-o', '@OUTPUT@',
-                             '-std=c++1z', '--js-library', JS_LIBRARY,
-                             '--js-library',
-                             files('compiled/bindings/library.js'),
-                             '@INPUT@'])
-bindings_output = custom_target('bindings-output',
-                input: bindings_generator,
-                output: BINDINGS_OUTPUT,
-                capture: true,
-                command: [nodejs, '@INPUT@'])
-
+shared_sources = [
+  'compiled/bindings/runtime_utils.cpp',
+  'compiled/filter/ActiveFilter.cpp',
+  'compiled/filter/BlockingFilter.cpp',
+  'compiled/filter/CommentFilter.cpp',
+  'compiled/filter/ElemHideBase.cpp',
+  'compiled/filter/ElemHideEmulationFilter.cpp',
+  'compiled/filter/ElemHideException.cpp',
+  'compiled/filter/ElemHideFilter.cpp',
+  'compiled/filter/Filter.cpp',
+  'compiled/filter/InvalidFilter.cpp',
+  'compiled/filter/RegExpFilter.cpp',
+  'compiled/filter/WhitelistFilter.cpp',
+  'compiled/storage/FilterStorage.cpp',
+  'compiled/subscription/DownloadableSubscription.cpp',
+  'compiled/subscription/Subscription.cpp',
+  'compiled/subscription/UserDefinedSubscription.cpp',
+]
+# sources specific to core
+core_sources = [
+  'compiled/traceInit.cpp',
+]
+# sources for the bindings generator
+bindings_sources = [
+  'compiled/bindings/generator.cpp',
+  'compiled/bindings/main.cpp',
+]
 
 defines_args = []
 foreach define : DEFINES
-        defines_args += '-D' + define
+  defines_args += '-D' + define
 endforeach
 
 generation_args = []
 foreach param : GENERATION_PARAMS
-        generation_args += '-s'
-        generation_args += param[0] + '=' + '@0@'.format(param[1])

[Wladimir Palant, 2017/10/11 10:00:47]

Nit: You should really unify leading whitespace in this file, we should use two
spaces for indentation.

[hub, 2017/10/11 18:23:16]

Done.

+  generation_args += '-s'
+  generation_args += param[0] + '=' + '@0@'.format(param[1])
 endforeach
 
 optional_args = []
-debug = get_option('buildtype')
-if debug.startswith('debug')
+buildtype = get_option('buildtype')
+if buildtype.startswith('debug')
+  optional_args += '-DDEBUG'
   optional_args += '-g3'
 endif
 tracing = get_option('tracing')
 if tracing
   optional_args += '--tracing'
 endif
 
-output_file = meson.source_root() + '/lib/' + COMPILER_OUTPUT
-compiler_output = custom_target('compiled.js',
-                build_by_default: true,
-                input: sources,
-                output: COMPILER_OUTPUT,

[Wladimir Palant, 2017/10/11 10:00:47]

I'd consider that a temporary hack. It's probably best to have compiled.js
generated in the build/ directory and adjust require() paths accordingly.

[hub, 2017/10/11 18:23:17]

Acknowledged.

-                command: [emcc, '-o', output_file, '-std=c++1z',

[Wladimir Palant, 2017/10/11 10:00:47]

-std=c++1z parameter is unnecessary here, it is already part of
ADDITIONAL_PARAMS.

[hub, 2017/10/11 18:23:16]

Done.

-                '--post-js', bindings_output, '@INPUT@'] +
-                defines_args + generation_args + optional_args +
-                ADDITIONAL_PARAMS)

[Wladimir Palant, 2017/10/11 10:00:47]

Object files should really be generated as separate targets, to make the builds
faster. If I make sources a list of strings rather than files, the following
works for me:

compiler_args = defines_args + generation_args + optional_args +
ADDITIONAL_PARAMS

objects = []
foreach source_file : sources
  output_file = source_file + '.o'
  objects += custom_target(output_file,
                           input: files(source_file),
                           output: source_file.underscorify() + '.o',
                           command: [emcc, '-c', '-o', '@OUTPUT@', '@INPUT@'] +
                                    compiler_args)
endforeach

output_file = meson.source_root() + '/lib/' + COMPILER_OUTPUT
compiler_output = custom_target('compiled.js',
                build_by_default: true,
                input: objects,
                output: COMPILER_OUTPUT,
                command: [emcc, '-o', output_file, '--post-js', bindings_output,
                          '@INPUT@'] + compiler_args)

[hub, 2017/10/11 18:23:16]

I wanted to use the c++ targets, but meson doesn't allow overriding the compiler
- expect by passing environment, which we don't want to have too. It is a
feature according to them.

Your suggestion make sense.

[Wladimir Palant, 2017/10/11 21:01:23]

That's too bad. It would have been much nicer if we could tell to use emcc like
the regular clang.

+compiler_args = defines_args + generation_args + ADDITIONAL_PARAMS
+
+# build objects.
+core_objects = []
+bindings_objects = []
+shared_objects = []
+foreach group : ['core', 'bindings', 'shared']
+  objects = []
+  foreach source_file : get_variable(group + '_sources')
+    output_file = source_file.underscorify() + '.o'
+    command = [ emcc, '-MD', '-MF', '@DEPFILE@', '-c', '-o', '@OUTPUT@',
+                '@INPUT@' ] + compiler_args
+    if group != 'bindings'
+      command += CORE_PARAMS + optional_args
+    endif
+    objects += custom_target(output_file,
+                             input: files(source_file),
+                             output: output_file,
+                             depfile: output_file + '.deps',
+                             command: command)
+  endforeach
+  # Ideally, we would call set_variable() here but that doesn't work with arrays
+  # (see https://github.com/mesonbuild/meson/issues/1481). So we have to do this
+  # shifting dance instead.
+  core_objects = bindings_objects
+  bindings_objects = shared_objects
+  shared_objects = objects
+endforeach
+
+# link the binding generator
+bindings_generator = custom_target(BINDINGS_GENERATOR,
+                                   input: bindings_objects + shared_objects,
+                                   output: BINDINGS_GENERATOR,
+                                   depend_files: [ JS_LIBRARY, BINDINGS_JS_LIBRARY ],
+                                   command: [
+                                     emcc, '-o', '@OUTPUT@',
+                                     '--js-library', JS_LIBRARY,
+                                     '--js-library', BINDINGS_JS_LIBRARY,
+                                     '@INPUT@'
+                                   ])
+# run the binding generator
+bindings_output = custom_target(BINDINGS_OUTPUT,
+                                input: bindings_generator,
+                                output: BINDINGS_OUTPUT,
+                                capture: true,
+                                command: [nodejs, '@INPUT@'])
+
+# link the core
+output_file = join_paths(meson.source_root(), 'lib', COMPILER_OUTPUT)
+compiler_output = custom_target(COMPILER_OUTPUT,
+                                build_by_default: true,
+                                input: core_objects + shared_objects,
+                                output: COMPILER_OUTPUT,
+                                depend_files: [ JS_LIBRARY ],
+                                command: [
+                                  emcc, '-o', output_file,
+                                  '--post-js', bindings_output,
+                                  '--js-library', JS_LIBRARY,
+                                  '@INPUT@'
+                                ] + compiler_args + optional_args)