#2687 - Include mimeo python module

modules/adblockplus/manifests/web/mimeo.pp

 # == Class: adblockplus::web::mimeo
 #
-# A [mimeograph](https://en.wikipedia.org/wiki/Mimeograph) (also known as stencil duplicator) is a low-cost duplicating
-# machine. Mimeo is used here since it is the abbreviation and it sounds better.
+# Class adblockplus::web::mimeo registers the information received in a
+# http/s petition with an specified format in an specific output.
 #
-# The pourpose of this class is to log the information received in a http/s
-# petition with an specified format.
 # === Parameters:
 #
 # [*format*]
-#   A systemd escaped string containing the desired format for logging.
+#   A string containing the desired format for logging.
 #
 #   '$remote_addr - - [$time_local] "$request" $status $bytes_sent "$http_referer"'
-#
-#   This is an example of how the format would look like in the log file.
-#
-#   \x24remote_addr\x20\x2d\x20\x2d\x20\x5b\x24time_local\x5d\x20\x22\x24request\x22\x20\x24status\x20\x24bytes_sent\x20\x22\x24http_referer\x22
-#
-#   And this is how it looks escaped, for escaping is necessary to use
-#   `systemd-escape` command, since this parameter is passed to a systemd
-#   unit file.
 #
 # [*port*]
 #   An integer to setup the port where the script will be listening, defaults
 #   to 8000.
 #
 # [*response*]
-#   A systemd escaped string (like format parameter) representing the response
-#   sent to the client.
+#   A string (like format parameter) representing the response sent to the
+#   client.
 #
-# [*log_file*]
-#   A string containg the path to the file where the logs will be written.
 class adblockplus::web::mimeo (
   $format = '',
   $port = 8000,
   $response = '',
-  $log_file = '/var/log/mimeo.log',
 ){
+  include adblockplus
 
   ensure_packages(['python3'])
 
-  file {"/opt/mimeo":
+  realize(File['/var/adblockplus'])
+
+  file {'/var/adblockplus/mimeo':
     ensure => 'directory',
+    mode => '0755',
     owner => 'root',
-    group => 'root',
+    require => File['/var/adblockplus'],
   }
 
-  file {"/opt/mimeo/mimeo.py":

[mathias, 2017/08/09 21:09:07]

I don't think this requires an entire directory in /opt. And with it, one would
expect a bit more than a single file there. The directory is meant for software
which does not integrate with the LSB file structure. But we could just copy the
script to /usr/local/bin, make it executable and be done with it.

[f.lopez, 2017/08/10 19:06:34]

Done.

+  file {'/usr/local/bin/mimeo.py':
     ensure => 'present',
     owner => 'root',
     group => 'root',
-    mode => 0644,
-    content => file('adblockplus/mimeo.py'),
-    require => File["/opt/mimeo"],

[mathias, 2017/08/09 21:09:07]

I'd consider Package['python3'] a requirement of the script already, not the
service resource defined below.

[f.lopez, 2017/08/10 19:06:35]

Done.

+    mode => 0755,
+    source => 'puppet:///modules/adblockplus/mimeo.py',
+    require => Package['python3'],
   }
 
-  file {"/etc/systemd/system/mimeo.service":
+  file {'/etc/systemd/system/mimeo.service':
     ensure => 'present',
     owner => 'root',
     group => 'root',
     mode => 0644,
     content => template('adblockplus/mimeo.service.erb'),

[mathias, 2017/08/09 21:09:07]

I'd consider the mimeo.py script a requirement of the service unit.

[f.lopez, 2017/08/10 19:06:35]

Done.

+    require => File['/usr/local/bin/mimeo.py'],
   }
 
   Exec{
     path => ['/usr/bin', '/bin'],
   }
 
-  exec {"enable-service-mimeo":
+  exec {'enable-service-mimeo':
     command => 'systemctl enable mimeo.service',
     user => 'root',
-    onlyif => 'systemctl is-enabled mimeo.service | grep disabled',

[mathias, 2017/08/09 21:09:07]

You can use parameter $unless and avoid grep by relying on the exit code.

[f.lopez, 2017/08/10 19:06:35]

Done.

-    require => File["/etc/systemd/system/mimeo.service"],
+    unless => 'systemctl is-enabled mimeo.service',
+    require => File['/etc/systemd/system/mimeo.service'],
   }
 
-  service {"mimeo.service":

[mathias, 2017/08/09 21:09:07]

Just call it Service['mimeo'] please, in Puppet the extension is kind of
redundant.

[f.lopez, 2017/08/10 19:06:34]

Done.

+  service {'mimeo':
     ensure => 'running',
     hasrestart => false,
     provider => 'systemd',
-    require => [
-      Exec["enable-service-mimeo"],
-      Package["python3"],
-    ],
+    require => Exec['enable-service-mimeo'],
+    subscribe => File['/usr/local/bin/mimeo.py'],
   }
 
-  exec {"reload-mimeo-daemon":
+  exec {'reload-mimeo-daemon':
+    notify => Service['mimeo'],
     command => 'systemctl daemon-reload',
-    subscribe => File["/etc/systemd/system/mimeo.service"],
+    subscribe => File['/etc/systemd/system/mimeo.service'],
     refreshonly => true,
   }
 }