#2687 - Include mimeo python module

modules/adblockplus/manifests/web/mimeo.pp

 # == Class: adblockplus::web::mimeo
 #
-# A [mimeograph](https://en.wikipedia.org/wiki/Mimeograph) (also known as stencil duplicator) is a low-cost duplicating
-# machine. Mimeo is used here since it is the abbreviation and it sounds better.

[mathias, 2017/08/18 08:47:44]

Please don't explain naming unless absolutely necessary.

[f.lopez, 2017/08/19 00:51:01]

Done.

+# Class adblockplus::web::mimeo registers the information received in a
+# http/s petition with an specified format in an specific output.
 #
-# The pourpose of this class is to log the information received in a http/s

[mathias, 2017/08/18 08:47:45]

Please name the item the fuzz is about and avoid non-content, i.e. "Class foobar
maintains a ..." vs "The purpose of this class is to maintain a ...".

[f.lopez, 2017/08/19 00:51:02]

Done.

-# petition with an specified format.
 # === Parameters:

[mathias, 2017/08/18 08:47:46]

There should be a `#`-only line above this one.

[f.lopez, 2017/08/19 00:51:02]

Done.

 #
 # [*format*]
 #   A string containing the desired format for logging.
 #
 #   '$remote_addr - - [$time_local] "$request" $status $bytes_sent "$http_referer"'
 #
 # [*port*]
 #   An integer to setup the port where the script will be listening, defaults
 #   to 8000.
 #
 # [*response*]
 #   A string (like format parameter) representing the response sent to the
 #   client.
 #
-# [*log_file*]
-#   A string containg the path to the file where the logs will be written.
 class adblockplus::web::mimeo (

[mathias, 2017/08/18 08:47:45]

There should be a `#`-only line above this one as well.

[f.lopez, 2017/08/19 00:51:02]

Done.

   $format = '',
   $port = 8000,
   $response = '',
-  $log_file = '/var/log/mimeo.log',

[mathias, 2017/08/18 08:47:44]

Again this is not logging in the word's sense within our technical language
domain, and it was merely a coincidence that we've been using logging mechanisms
for the tasks we now want to do with the `mimeo.py` script. So please use some
terminology that avoids the confusion, i.e. `output` or `data` or similar, and
use some path in `/var/adblockplus/mimeo/` or similar.

[f.lopez, 2017/08/19 00:51:01]

I'll just default it to '-' (stdout)

 ){
+  include adblockplus
 
   ensure_packages(['python3'])
 
-  file {"/usr/local/bin/mimeo.py":
+  realize(File['/var/adblockplus'])
+
+  file {'/var/adblockplus/mimeo':
+    ensure => 'directory',
+    mode => '0755',
+    owner => 'root',
+    require => File['/var/adblockplus'],
+  }
+
+  file {'/usr/local/bin/mimeo.py':
     ensure => 'present',
     owner => 'root',
     group => 'root',
     mode => 0755,
-    content => file('adblockplus/mimeo.py'),

[mathias, 2017/08/18 08:47:46]

Why use $content/file() here instead of $source?

+    source => 'puppet:///modules/adblockplus/mimeo.py',
     require => Package['python3'],
   }
 
-  file {"/etc/systemd/system/mimeo.service":
+  file {'/etc/systemd/system/mimeo.service':
     ensure => 'present',
     owner => 'root',
     group => 'root',
     mode => 0644,
     content => template('adblockplus/mimeo.service.erb'),
     require => File['/usr/local/bin/mimeo.py'],
   }
 
   Exec{
     path => ['/usr/bin', '/bin'],
   }
 
-  exec {"enable-service-mimeo":
+  exec {'enable-service-mimeo':
     command => 'systemctl enable mimeo.service',
     user => 'root',
     unless => 'systemctl is-enabled mimeo.service',
-    require => File["/etc/systemd/system/mimeo.service"],
+    require => File['/etc/systemd/system/mimeo.service'],
   }
 
-  service {"mimeo":
+  service {'mimeo':
     ensure => 'running',
     hasrestart => false,
     provider => 'systemd',
-    require => [
-      Exec["enable-service-mimeo"],
-      Package["python3"],

[mathias, 2017/08/18 08:47:46]

The service should be able to rely on the script managing it's own dependencies,
so there should be no need to declare a relationship with Python here.

[f.lopez, 2017/08/19 00:51:02]

Done.

-    ],
+    require => Exec['enable-service-mimeo'],
+    subscribe => File['/usr/local/bin/mimeo.py'],
   }
 
-  exec {"reload-mimeo-daemon":
+  exec {'reload-mimeo-daemon':
+    notify => Service['mimeo'],
     command => 'systemctl daemon-reload',

[mathias, 2017/08/18 08:47:45]

Does daemon-reload include a service restart if necessary? Not sure but I don't
think so, in which case changing the mimeo.service file would not currently
result in a restart.

[f.lopez, 2017/08/19 00:51:01]

Heh, you are right, I forgot to notify the service.

-    subscribe => File["/etc/systemd/system/mimeo.service"],
+    subscribe => File['/etc/systemd/system/mimeo.service'],
     refreshonly => true,
   }
 }