Noissue - Use meson to build the C++ code

meson.build

+project('adblockpluscore', 'cpp', license: ['GPL3'])

[Wladimir Palant, 2017/10/11 21:01:23]

I suspect that the build will now fail if no C++ compiler is found on the
system. If that's the case, requiring a newer meson version should be the lesser
evil...

[sergei, 2017/10/16 15:27:11]

Yes, it fails if it cannot find any C++ compiler, e.g. it does not work on
Windows.

+
+# locate emscripten-config
+python = import('python3').find_python()
+emscripten_config = get_option('emscripten-config')
+command = run_command(python, '-c', 'import os.path, sys;print(os.path.expanduser(sys.argv[1]))', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+emscripten_config = command.stdout().strip()
+message('Emscripten config file: ' + emscripten_config)
+
+# locate emcc
+command = run_command(python, '-c', 'import sys;exec(open(sys.argv[1]).read());print(EMSCRIPTEN_ROOT)', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+emcc = join_paths(command.stdout().strip(), 'emcc')
+emcc = find_program(emcc)
+
+# locate node
+command = run_command(python, '-c', 'import sys;exec(open(sys.argv[1]).read());print(NODE_JS)', emscripten_config)
+if command.returncode() != 0
+  error(command.stderr().strip())
+endif
+nodejs = find_program(command.stdout().strip(), 'node', 'nodejs')
+
+JS_LIBRARY = files(join_paths('compiled', 'library.js'))
+BINDINGS_GENERATOR = 'bindings.cpp.js'
+BINDINGS_OUTPUT = 'bindings.js'
+COMPILER_OUTPUT = 'compiled.js'
+# params for emcc compilation
+ADDITIONAL_PARAMS = ['-O3', '-m32', '-std=c++1z', '--memory-init-file', '0',
+                     '--emit-symbol-map', '-Wall', '-Werror', '-fno-exceptions',
+                     '-fno-rtti', '--js-library', JS_LIBRARY]
+DEFINES = []
+GENERATION_PARAMS = [
+  ['SHELL_FILE', '"' +
+   join_paths(meson.source_root(), 'compiled', 'shell.js') +
+   '"'],
+  ['ASM_JS', '2'],  # "almost asm"
+  ['TOTAL_MEMORY', 16*1024*1024],
+  ['TOTAL_STACK', 1*1024*1024],
+  ['ALLOW_MEMORY_GROWTH', 1],
+  ['NO_EXIT_RUNTIME', 1],
+  ['NO_DYNAMIC_EXECUTION', 1],
+  ['NO_FILESYSTEM', 1],
+  ['INVOKE_RUN', 0],
+  ['TEXTDECODER', 0],
+  ['EXPORTED_RUNTIME_METHODS', '["cwrap", "ccall", "stringToAscii"]']
+]
+
+# We want these to be strings.
+core_sources = [ 'compiled/traceInit.cpp' ]
+sources = [
+  'compiled/bindings/runtime_utils.cpp',
+  'compiled/filter/ActiveFilter.cpp',
+  'compiled/filter/BlockingFilter.cpp',
+  'compiled/filter/CommentFilter.cpp',
+  'compiled/filter/ElemHideBase.cpp',
+  'compiled/filter/ElemHideEmulationFilter.cpp',
+  'compiled/filter/ElemHideException.cpp',
+  'compiled/filter/ElemHideFilter.cpp',
+  'compiled/filter/Filter.cpp',
+  'compiled/filter/InvalidFilter.cpp',
+  'compiled/filter/RegExpFilter.cpp',
+  'compiled/filter/WhitelistFilter.cpp',
+  'compiled/storage/FilterStorage.cpp',
+  'compiled/subscription/DownloadableSubscription.cpp',
+  'compiled/subscription/Subscription.cpp',
+  'compiled/subscription/UserDefinedSubscription.cpp',
+]
+
+
+# bindings
+bindings_sources = files(
+  'compiled/bindings/generator.cpp',
+  'compiled/bindings/main.cpp',
+)
+
+# convert the string list to a filesarray.
+foreach source : sources
+  bindings_sources += files(source)
+endforeach
+
+bindings_generator = custom_target('bindings-generator',
+                                   input: bindings_sources,
+                                   output: BINDINGS_GENERATOR,
+                                   command: [
+                                     emcc, '-o', '@OUTPUT@',
+                                     '-std=c++1z', '--js-library',
+                                     JS_LIBRARY,
+                                     '--js-library',
+                                     files('compiled/bindings/library.js'),
+                                     '@INPUT@'
+                                   ])
+bindings_output = custom_target('bindings-output',
+                                input: bindings_generator,
+                                output: BINDINGS_OUTPUT,
+                                capture: true,
+                                command: [nodejs, '@INPUT@'])
+
+
+defines_args = []
+foreach define : DEFINES
+  defines_args += '-D' + define
+endforeach
+
+generation_args = []
+foreach param : GENERATION_PARAMS
+  generation_args += '-s'
+  generation_args += param[0] + '=' + '@0@'.format(param[1])
+endforeach
+
+optional_args = []
+debug = get_option('buildtype')
+if debug.startswith('debug')
+  optional_args += '-g3'
+endif
+tracing = get_option('tracing')
+if tracing
+  optional_args += '--tracing'
+endif
+
+compiler_args = defines_args + generation_args + optional_args + ADDITIONAL_PARAMS
+
+# build objects.
+objects = []
+all_sources = sources + core_sources
+foreach source_file : all_sources
+   output_file = source_file.underscorify() + '.o'

[Wladimir Palant, 2017/10/12 08:46:09]

Nit: You have three spaces indentation here.

[hub, 2017/10/12 18:12:11]

Done.

+   objects += custom_target(output_file,
+                            input: files(source_file),
+                            output: output_file,
+                            command: [
+                              emcc, '-c', '-o', '@OUTPUT@', '@INPUT@'
+                            ] + compiler_args)

[Wladimir Palant, 2017/10/11 21:01:23]

I looked into dependencies generation and we need to specify a depsfile
parameter here as well as pass -MD and -MF parameters to emcc so that this file
is actually generated:

   objects += custom_target(output_file,
                            input: files(source_file),
                            output: output_file,
                            depfile: output_file + '.deps',
                            command: [
                              emcc, '-MD', '-MF', '@DEPFILE@', '-c',
                              '-o', '@OUTPUT@', '@INPUT@'
                            ] + compiler_args)

We would need the same thing for the bindings generator however.

[Wladimir Palant, 2017/10/12 08:46:09]

Actually, I succeeded reusing objects between bindings and main application
without duplicating too much code. For that I had to split out '-fno-exceptions'
from ADDITIONAL_PARAMS into CORE_PARAMS, this flag cannot be set for bindings
generator. I also renamed sources variable into shared_sources. The object
generation looks like this:

# build objects.
core_objects = []
bindings_objects = []
shared_objects = []
foreach group : ['core', 'bindings', 'shared']
  objects = []
  foreach source_file : get_variable(group + '_sources')
    output_file = source_file.underscorify() + '.o'
    command = [
      emcc, '-MD', '-MF', '@DEPFILE@', '-c',
      '-o', '@OUTPUT@', '@INPUT@'
    ] + compiler_args
    if group != 'bindings'
      command += CORE_PARAMS
    endif

    objects += custom_target(output_file,
                             input: files(source_file),
                             output: output_file,
                             depfile: output_file + '.deps',
                             command: command)
  endforeach

  # Ideally, we would call set_variable() here but that doesn't work with arrays
  # (see https://github.com/mesonbuild/meson/issues/1481). So we have to do this
  # shifting dance instead.
  core_objects = bindings_objects
  bindings_objects = shared_objects
  shared_objects = objects
endforeach

The bindings-generator target has to be moved below this code then and work on
bindings_objects + shared_objects. The '-std=c++1z' parameter is no longer
needed there. And the compiled.js target works on core_objects + shared_objects.

[hub, 2017/10/12 18:12:11]

Done.

[hub, 2017/10/12 18:12:11]

Done.

+endforeach
+
+# link it all.
+output_file = join_paths(meson.source_root(), 'lib', COMPILER_OUTPUT)
+compiler_output = custom_target('compiled.js',
+                                build_by_default: true,
+                                input: objects,
+                                output: COMPILER_OUTPUT,
+                                command: [
+                                  emcc, '-o', output_file,
+                                  '--post-js', bindings_output,
+                                  '@INPUT@'
+                                ] + compiler_args)