Issue 6591 - Bundle ABP for Samsung Internet China with Easylist for China

adblockplussbrowser/build.gradle

 apply plugin: 'com.android.application'
 apply plugin: 'kotlin-android'
 apply plugin: 'kotlin-android-extensions'
 
 android {
     compileSdkVersion rootProject.ext.compileSdkVersion
     buildToolsVersion rootProject.ext.buildToolsVersion
 
     compileOptions {
         sourceCompatibility = rootProject.ext.sourceCompatibilityVersion
         targetCompatibility = rootProject.ext.targetCompatibilityVersion
     }
 
     defaultConfig {
         applicationId "org.adblockplus.adblockplussbrowser"
         minSdkVersion rootProject.ext.minSdkVersion
         targetSdkVersion rootProject.ext.targetSdkVersion
         versionCode 14
         versionName '1.1.4'
+        buildConfigField "String", "FLAVOR_REGION_WORLD", '"world"'
+        buildConfigField "String", "FLAVOR_REGION_CHINA", '"china"'

[diegocarloslima, 2018/04/20 13:33:01]

Since the current flavor is defined at build time, I think its more logical to
define the flavor constants also here that can be used in the Java code

     }
 
     sourceSets {
         main {
             manifest.srcFile 'AndroidManifest.xml'
             res.srcDirs = ['res']
         }
     }
 
     buildTypes {
         release {
             minifyEnabled true
             proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
             lintOptions {
                 disable 'MissingTranslation'
             }
         }
     }
 
     flavorDimensions "region"
 
     productFlavors {
         world {
             dimension "region"
         }
 
-        cn {
+        china {

[diegocarloslima, 2018/04/20 13:33:01]

Renamed to make the flavor finding through the task name more reliable

             dimension "region"
             applicationIdSuffix ".cn"
         }
     }
 
     testOptions {
         unitTests {
             includeAndroidResources = true
         }
     }
 
     afterEvaluate { project ->
 
         project.tasks.all { task ->
             if (task.name.matches("generate.*Release.*Resources")) {
                 task.doLast {
-                    updateBundledLists()
+                    updateBundledLists(task.name)
                     println('Bundled lists updated at ' + new Date().format('dd MMM yyyy, HH:mm:ss zzz'))
                 }
             }
         }
     }
 }
 
-def updateBundledLists() {
-    new URL(rootProject.ext.easyListUpdateUrl).withInputStream {
+def updateBundledLists(taskName) {
+    def easylistUrl = taskName.contains("China") ?

[diegocarloslima, 2018/04/20 13:33:02]

I couldn't find any reliable and elegant way of determining the current flavor
that didn't use the task name :/

+            rootProject.ext.easyListChinaUpdateUrl : rootProject.ext.easyListDefaultUpdateUrl
+    new URL(easylistUrl).withInputStream {
         i -> new File(rootProject.ext.easyListFilePath).withOutputStream { it << i }
     }
     new URL(rootProject.ext.exceptionRulesUpdateUrl).withInputStream {
         i -> new File(rootProject.ext.exceptionRulesFilePath).withOutputStream { it << i }
     }
 }
 
 dependencies {
     testImplementation "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlinVersion"
     testImplementation 'junit:junit:4.12'
     testImplementation 'org.mockito:mockito-core:2.16.0'
     testImplementation 'org.robolectric:robolectric:3.8'
     implementation "com.android.support:support-v4:$rootProject.ext.androidSupportLibraryVersion"
     implementation (group: 'commons-validator', name: 'commons-validator', version: '1.6') {
         exclude group: 'commons-logging', module: 'commons-logging'
     }
 }