Concept for Trac as issue tracker.

modules/trac/manifests/init.pp

-class trac($domain) inherits private::trac {
-  package {['python-mysqldb','python-setuptools','subversion']: ensure => present}

[Wladimir Palant, 2014/03/03 08:44:31]

Style nit: Could you please put |ensure => present| on the next line, like we do
it everywhere?

+class trac(
+    $domain,
+    $is_default = false) inherits private::trac {
+  package {['python-mysqldb','python-pip','subversion', 'tofrodos', 'graphviz']:
+    ensure => present
+  }
 
-  include nginx
+  include nginx, spawn-fcgi
 
   nginx::hostconfig {$domain:
     content => template('trac/site.erb'),
     enabled => true
   }
 
   user {'trac':
     ensure => present,
     comment => 'User of the trac installation',
     home => '/home/trac',
     managehome => true
   }
-  
+
   class {'mysql::server':
-    config_hash => {'root_password' => $database_root_password}
+    root_password => $database_root_password
   }
 
   mysql::db {'trac':
     user => 'trac',
     password => $database_password,
     host => 'localhost',
     grant => ['all'],
-    require => Class['mysql::config']
+    charset => 'utf8',
+    collate => 'utf8_bin',
+    require => Class['mysql::server']
   }
 
   Exec {
     path => '/usr/bin:/usr/sbin:/bin:/usr/local/bin',
   }
 
-  exec { 'collate':
-    command => "echo \"ALTER DATABASE trac DEFAULT CHARACTER SET utf8 COLLATE utf8_bin;\" | mysql -u trac -p${database_password}",
-  require => Mysql::Db['trac']

[Wladimir Palant, 2014/03/03 08:44:31]

Please add charset => 'utf8 COLLATE utf8_bin' to the mysql::db macro above
instead of running raw SQL here.

-  }
-
   exec { 'install_trac':
-    command => "easy_install Trac==1.0",

[Wladimir Palant, 2014/03/03 08:44:31]

We might want to use the python-pip package and |pip install Trac==1.0| instead
- pip seems to be generally more flexible than setuptools.

-    require => [
-        Package['python-mysqldb', 'python-setuptools'],
-        Exec['collate']],
-    unless => "which tracd"

[Wladimir Palant, 2014/03/03 08:44:31]

We might prefer something like "python -c 'import
trac,sys;sys.exit(trac.__version__ != \"1.0\")'" here - this will allow
upgrading to a newer Trac version in future. Also, this approach will work for
other modules as well.

+    command => "pip install Trac==1.0",
+    require => Package['python-pip'],
+    unless => "python -c 'import trac,sys;sys.exit(0 if trac.__version__ == \"1.0\" else 1)'",
   }
 
   exec { 'trac_env':
     command => "trac-admin /home/trac/environment initenv \"Adblock Plus issue tracker\" mysql://trac:${database_password}@localhost:3306/trac",
-    require => Exec['install_trac'],
+    require => [
+      Exec['install_trac'],
+      Mysql_grant['trac@localhost/trac.*']
+    ],
     user => trac,
-    onlyif => "test ! -d /home/trac/environment"
+    unless => "test -d /home/trac/environment"
   }
 
-
   exec { 'install_BlackMagicTicketTweaks':
-    command => "easy_install http://trac-hacks.org/svn/blackmagictickettweaksplugin/0.12/",
-    require => [
-        Package['subversion'],
-        Exec['trac_env']]

[Wladimir Palant, 2014/03/03 08:44:31]

This doesn't really depend on the trac enviroment, rather on
Package['python-setuptools']. Same for the other modules below.

Also, we need to check here whether the right module version is already
installed, similarly to how we do it for trac.

+    command => "pip install svn+http://trac-hacks.org/svn/blackmagictickettweaksplugin/0.12/",
+    require => Package['subversion', 'python-pip'],
+    unless => "python -c 'import blackmagic'",
   }
 
   exec { 'install_SensitiveTickets':
-    command => "easy_install http://trac-hacks.org/svn/sensitiveticketsplugin/trunk/",
-    require => [
-        Package['subversion'],
-        Exec['trac_env']]
+    command => "pip install svn+http://trac-hacks.org/svn/sensitiveticketsplugin/trunk/",
+    require => Package['subversion', 'python-pip'],
+    unless => "python -c 'import sensitivetickets'",
   }
 
   exec { 'install_AccountManager':
-    command => "easy_install http://trac-hacks.org/svn/accountmanagerplugin/tags/acct_mgr-0.4.3/",
-    require => [
-        Package['subversion'],
-        Exec['trac_env']]
+    command => "pip install svn+http://trac-hacks.org/svn/accountmanagerplugin/tags/acct_mgr-0.4.3/",
+    require => Package['subversion', 'python-pip'],
+    unless => "python -c 'import acct_mgr'",
   }
 
-
   exec { 'install_TicketTemplate':
-    command => "easy_install http://trac-hacks.org/svn/tractickettemplateplugin/0.11/",
-    require => [
-        Package['subversion'],
-        Exec['trac_env']]
+    command => "pip install svn+http://trac-hacks.org/svn/tractickettemplateplugin/0.11/",
+    require => Package['subversion', 'python-pip'],
+    unless => "python -c 'import tickettemplate'",
   }
 
+  exec { 'install_AutocompleteUsers':
+    command => "pip install svn+http://trac-hacks.org/svn/autocompleteusersplugin/trunk/",
+    require => Package['subversion', 'python-pip'],
+    unless => "python -c 'import autocompleteusers'",
+  }
 
-  exec { 'install_AutocompleteUsers':
-    command => "easy_install http://trac-hacks.org/svn/autocompleteusersplugin/trunk/",
-    require => [
-        Package['subversion'],
-        Exec['trac_env']]
+  exec { 'install_MasterTickets':
+    command => "pip install svn+http://trac-hacks.org/svn/masterticketsplugin/trunk/",
+    require => Package['subversion', 'python-pip', 'graphviz'],
+    unless => "python -c 'import mastertickets'",
   }
 
   file {"/home/trac/environment/conf/trac.ini":
     ensure => present,
     content => template('trac/trac.ini.erb'),
+    owner => trac,
     require => Exec['trac_env']
   }
 
-  file {"/home/trac/environment/htdocs/adblockplus_logo.png":
+  file {"/home/trac/htdocs/htdocs/common/adblockplus_logo.png":
     ensure => present,
     source => 'puppet:///modules/trac/adblockplus_logo.png',
-    require => Exec['trac_env']
-  }
-
-  exec {"tracd":
-    command => "tracd --port 8088 -d -s /home/trac/environment",

[Wladimir Palant, 2014/03/03 08:44:31]

This needs to run as a service, otherwise it won't restart on reboot for
example. This should be best done via FCGI - you can use spawn-fcgi::pool class
for that (see modules/web/manifests/server.pp for an example). This will also
allow using a Unix domain socket instead of a TCP port.

-    require => [
-        Exec['install_SensitiveTickets'],
-        Exec['install_BlackMagicTicketTweaks'],
-        Exec['install_AccountManager'],
-        Exec['install_AutocompleteUsers'],
-        Exec['install_TicketTemplate']]
+    owner => trac,
+    require => Exec['deploy']
   }
 
   exec {"update_env":
     command => "trac-admin /home/trac/environment upgrade",

[Wladimir Palant, 2014/03/03 08:44:31]

Shouldn't we rather initialize the environment only after all the modules are
installed?

[Philip Hill, 2014/03/06 14:50:20]

As far as I unterstood, installing Plugins requires an alreaey set up
environment.

+    user => trac,
     require => [
-        Exec['install_SensitiveTickets'],
-        Exec['install_BlackMagicTicketTweaks'],
-        Exec['install_AccountManager'],
-        Exec['install_AutocompleteUsers'],
-        Exec['install_TicketTemplate']]
+      File['/home/trac/environment/conf/trac.ini'],
+      Exec['install_SensitiveTickets'],
+      Exec['install_BlackMagicTicketTweaks'],
+      Exec['install_AccountManager'],
+      Exec['install_AutocompleteUsers'],
+      Exec['install_TicketTemplate'],
+      Exec['install_MasterTickets']]
+  }
+
+  exec {"deploy":
+    command => "trac-admin /home/trac/environment deploy /home/trac/htdocs && fromdos /home/trac/htdocs/cgi-bin/trac.fcgi && chmod 755 /home/trac/htdocs/cgi-bin/trac.fcgi",
+    user => trac,
+    require => [
+      Exec["update_env"],
+      Package["tofrodos"]]
+  }
+
+  spawn-fcgi::pool {"tracd":
+    ensure => present,
+    fcgi_app => "/home/trac/htdocs/cgi-bin/trac.fcgi",
+    socket => "/tmp/trac-fastcgi.sock",
+    mode => "0666",
+    user => trac,
+    children => 1,
+    require => Exec['deploy'],
   }
 
   file {"/home/trac/permissions.csv":
     ensure => present,
-    source => 'puppet:///modules/trac/permissions.csv',
-    require => Exec['trac_env']
-  }
-
-  exec { "set_permission_groups":
-    command => "trac-admin /home/trac/environment permission import /home/trac/permissions.csv",

[Wladimir Palant, 2014/03/03 08:44:31]

I don't think that we want to run that every time we provision the server.
Probably best to merge it with the environment initialization (trac-admin
initenv && trac-admin permission import)

-    require => [
-        Exec['trac_env'],
-        File['/home/trac/environment/conf/trac.ini']]
+    owner => trac,
+    source => 'puppet:///modules/trac/permissions.csv'
   }
 
 }